'
' Solves FIGURE IT OUT - The Age newspaper
'
' Puzzle by Albert Haddad - www.theage.com.au
'
'   D  J  C  F  J  24
'   B  F  E  G  H  27
'   J  A  ?  B  K  21
'   D  C  F  K  A  20
'   E  H  D  G  B  24
'
'  16 23 25 32 20
'
'
' Where E=2, K=6, others 0,1,3,4,5,7,8,9
'       and ? is either A,B,C,D,E,F,G,H,J,K
'
'
' QBASIC by P.King - www.procontechnology.com.au
'
' Process - systematic selection of numbers until solution
' found. Maximum 8!=8x7x6x5x4x3x2x1 = 40,320 iterations.
'

DEFINT A-Z

DIM B(7) AS INTEGER
DIM C(7) AS INTEGER
DIM I(7) AS INTEGER

DIM T1 AS LONG

CLS

DO

C(0) = 0
C(1) = 1
C(2) = 3
C(3) = 4
C(4) = 5
C(5) = 7
C(6) = 8
C(7) = 9

FOR n0 = 7 TO 0 STEP -1
	B(n0) = C(I(n0))
	C(I(n0)) = C(n0)
NEXT n0

A = B(0)
B = B(1)
C = B(2)
D = B(3)
E = 2        'given!
F = B(4)
G = B(5)
H = B(6)
J = B(7)
K = 6        'given!

T1 = T1 + 1
IF T1 MOD 100 THEN  ELSE PRINT T1

IF D + J + C + F + J = 24 THEN
  IF B + F + E + G + H = 27 THEN
	IF D + C + F + K + A = 20 THEN
	  IF E + H + D + G + B = 24 THEN
		IF D + B + J + D + E = 16 THEN
		  IF J + F + A + C + H = 23 THEN
			IF F + G + B + K + G = 32 THEN
			  IF J + H + K + A + B = 20 THEN
				PRINT
				PRINT " A ="; A; " B ="; B; " C ="; C; " D ="; D; " E ="; E;
				PRINT " F ="; F; " G ="; G; " H ="; H; " J ="; J; " K ="; K
				PRINT
				END
			  END IF
			END IF
		  END IF
		END IF
	  END IF
	END IF
  END IF
END IF

n0 = 7
I(n0) = I(n0) + 1

DO WHILE I(n0) > n0
	I(n0) = 0
	n0 = n0 - 1
	IF n0 < 1 THEN
		PRINT
		PRINT " No solution possible!"
		END
	END IF
	I(n0) = I(n0) + 1
LOOP


LOOP UNTIL INKEY$ <> ""